Home | History | Annotate | Download | only in test 
      1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
      2 // Use of this source code is governed by a BSD-style license that can be
      3 // found in the LICENSE file.
      4 
      5 #import <UIKit/UIKit.h>
      6 
      7 #include "base/debug/debugger.h"
      8 #include "base/logging.h"
      9 #include "base/mac/scoped_nsautorelease_pool.h"
     10 #include "base/mac/scoped_nsobject.h"
     11 #include "base/message_loop/message_loop.h"
     12 #include "base/message_loop/message_pump_default.h"
     13 #include "base/test/test_suite.h"
     14 
     15 // Springboard will kill any iOS app that fails to check in after launch within
     16 // a given time. Starting a UIApplication before invoking TestSuite::Run
     17 // prevents this from happening.
     18 
     19 // InitIOSRunHook saves the TestSuite and argc/argv, then invoking
     20 // RunTestsFromIOSApp calls UIApplicationMain(), providing an application
     21 // delegate class: ChromeUnitTestDelegate. The delegate implements
     22 // application:didFinishLaunchingWithOptions: to invoke the TestSuite's Run
     23 // method.
     24 
     25 // Since the executable isn't likely to be a real iOS UI, the delegate puts up a
     26 // window displaying the app name. If a bunch of apps using MainHook are being
     27 // run in a row, this provides an indication of which one is currently running.
     28 
     29 static base::TestSuite* g_test_suite = NULL;
     30 static int g_argc;
     31 static char** g_argv;
     32 
     33 @interface UIApplication (Testing)
     34 - (void) _terminateWithStatus:(int)status;
     35 @end
     36 
     37 @interface ChromeUnitTestDelegate : NSObject {
     38  @private
     39   base::scoped_nsobject<UIWindow> window_;
     40 }
     41 - (void)runTests;
     42 @end
     43 
     44 @implementation ChromeUnitTestDelegate
     45 
     46 - (BOOL)application:(UIApplication *)application
     47     didFinishLaunchingWithOptions:(NSDictionary *)launchOptions {
     48 
     49   CGRect bounds = [[UIScreen mainScreen] bounds];
     50 
     51   // Yes, this is leaked, it's just to make what's running visible.
     52   window_.reset([[UIWindow alloc] initWithFrame:bounds]);
     53   [window_ makeKeyAndVisible];
     54 
     55   // Add a label with the app name.
     56   UILabel* label = [[[UILabel alloc] initWithFrame:bounds] autorelease];
     57   label.text = [[NSProcessInfo processInfo] processName];
     58   label.textAlignment = NSTextAlignmentCenter;
     59   [window_ addSubview:label];
     60 
     61   if ([self shouldRedirectOutputToFile])
     62     [self redirectOutput];
     63 
     64   // Queue up the test run.
     65   [self performSelector:@selector(runTests)
     66              withObject:nil
     67              afterDelay:0.1];
     68   return YES;
     69 }
     70 
     71 // Returns true if the gtest output should be redirected to a file, then sent
     72 // to NSLog when compleete. This redirection is used because gtest only writes
     73 // output to stdout, but results must be written to NSLog in order to show up in
     74 // the device log that is retrieved from the device by the host.
     75 - (BOOL)shouldRedirectOutputToFile {
     76 #if !TARGET_IPHONE_SIMULATOR
     77   return !base::debug::BeingDebugged();
     78 #endif  // TARGET_IPHONE_SIMULATOR
     79   return NO;
     80 }
     81 
     82 // Returns the path to the directory to store gtest output files.
     83 - (NSString*)outputPath {
     84   NSArray* searchPath =
     85       NSSearchPathForDirectoriesInDomains(NSDocumentDirectory,
     86                                           NSUserDomainMask,
     87                                           YES);
     88   CHECK([searchPath count] > 0) << "Failed to get the Documents folder";
     89   return [searchPath objectAtIndex:0];
     90 }
     91 
     92 // Returns the path to file that stdout is redirected to.
     93 - (NSString*)stdoutPath {
     94   return [[self outputPath] stringByAppendingPathComponent:@"stdout.log"];
     95 }
     96 
     97 // Returns the path to file that stderr is redirected to.
     98 - (NSString*)stderrPath {
     99   return [[self outputPath] stringByAppendingPathComponent:@"stderr.log"];
    100 }
    101 
    102 // Redirects stdout and stderr to files in the Documents folder in the app's
    103 // sandbox.
    104 - (void)redirectOutput {
    105   freopen([[self stdoutPath] UTF8String], "w+", stdout);
    106   freopen([[self stderrPath] UTF8String], "w+", stderr);
    107 }
    108 
    109 // Reads the redirected gtest output from a file and writes it to NSLog.
    110 - (void)writeOutputToNSLog {
    111   for (NSString* path in @[ [self stdoutPath], [self stderrPath]]) {
    112     NSString* content = [NSString stringWithContentsOfFile:path
    113                                                   encoding:NSUTF8StringEncoding
    114                                                      error:NULL];
    115     NSArray* lines = [content componentsSeparatedByCharactersInSet:
    116         [NSCharacterSet newlineCharacterSet]];
    117 
    118     NSLog(@"Writing contents of %@ to NSLog", path);
    119     for (NSString* line in lines) {
    120       NSLog(@"%@", line);
    121     }
    122   }
    123 }
    124 
    125 - (void)runTests {
    126   int exitStatus = g_test_suite->Run();
    127 
    128   if ([self shouldRedirectOutputToFile])
    129     [self writeOutputToNSLog];
    130 
    131   // If a test app is too fast, it will exit before Instruments has has a
    132   // a chance to initialize and no test results will be seen.
    133   // TODO(ios): crbug.com/137010 Figure out how much time is actually needed,
    134   // and sleep only to make sure that much time has elapsed since launch.
    135   [NSThread sleepUntilDate:[NSDate dateWithTimeIntervalSinceNow:2.0]];
    136   window_.reset();
    137 
    138   // Use the hidden selector to try and cleanly take down the app (otherwise
    139   // things can think the app crashed even on a zero exit status).
    140   UIApplication* application = [UIApplication sharedApplication];
    141   [application _terminateWithStatus:exitStatus];
    142 
    143   exit(exitStatus);
    144 }
    145 
    146 @end
    147 
    148 namespace {
    149 
    150 base::MessagePump* CreateMessagePumpForUIForTests() {
    151   // A default MessagePump will do quite nicely in tests.
    152   return new base::MessagePumpDefault();
    153 }
    154 
    155 }  // namespace
    156 
    157 namespace base {
    158 
    159 void InitIOSTestMessageLoop() {
    160   MessageLoop::InitMessagePumpForUIFactory(&CreateMessagePumpForUIForTests);
    161 }
    162 
    163 void InitIOSRunHook(TestSuite* suite, int argc, char* argv[]) {
    164   g_test_suite = suite;
    165   g_argc = argc;
    166   g_argv = argv;
    167 }
    168 
    169 void RunTestsFromIOSApp() {
    170   // When TestSuite::Run is invoked it calls RunTestsFromIOSApp(). On the first
    171   // invocation, this method fires up an iOS app via UIApplicationMain. Since
    172   // UIApplicationMain does not return until the app exits, control does not
    173   // return to the initial TestSuite::Run invocation, so the app invokes
    174   // TestSuite::Run a second time and since |ran_hook| is true at this point,
    175   // this method is a no-op and control returns to TestSuite:Run so that test
    176   // are executed. Once the app exits, RunTestsFromIOSApp calls exit() so that
    177   // control is not returned to the initial invocation of TestSuite::Run.
    178   static bool ran_hook = false;
    179   if (!ran_hook) {
    180     ran_hook = true;
    181     mac::ScopedNSAutoreleasePool pool;
    182     int exit_status = UIApplicationMain(g_argc, g_argv, nil,
    183                                         @"ChromeUnitTestDelegate");
    184     exit(exit_status);
    185   }
    186 }
    187 
    188 }  // namespace base
    189