Home | History | Annotate | Download | only in resource 
      1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
      2 // Use of this source code is governed by a BSD-style license that can be
      3 // found in the LICENSE file.
      4 
      5 #include "ui/base/resource/resource_bundle.h"
      6 
      7 #import <AppKit/AppKit.h>
      8 
      9 #include "base/basictypes.h"
     10 #include "base/file_util.h"
     11 #include "base/files/file_path.h"
     12 #include "base/mac/bundle_locations.h"
     13 #include "base/mac/mac_util.h"
     14 #include "base/mac/scoped_nsobject.h"
     15 #include "base/memory/ref_counted_memory.h"
     16 #include "base/strings/sys_string_conversions.h"
     17 #include "base/synchronization/lock.h"
     18 #include "ui/base/resource/resource_handle.h"
     19 #include "ui/gfx/image/image.h"
     20 
     21 namespace ui {
     22 
     23 namespace {
     24 
     25 base::FilePath GetResourcesPakFilePath(NSString* name, NSString* mac_locale) {
     26   NSString *resource_path;
     27   // Some of the helper processes need to be able to fetch resources
     28   // (chrome_main.cc: SubprocessNeedsResourceBundle()). Fetch the same locale
     29   // as the already-running browser instead of using what NSBundle might pick
     30   // based on values at helper launch time.
     31   if ([mac_locale length]) {
     32     resource_path = [base::mac::FrameworkBundle() pathForResource:name
     33                                                            ofType:@"pak"
     34                                                       inDirectory:@""
     35                                                   forLocalization:mac_locale];
     36   } else {
     37     resource_path = [base::mac::FrameworkBundle() pathForResource:name
     38                                                            ofType:@"pak"];
     39   }
     40 
     41   if (!resource_path) {
     42     // Return just the name of the pack file.
     43     return base::FilePath(base::SysNSStringToUTF8(name) + ".pak");
     44   }
     45 
     46   return base::FilePath([resource_path fileSystemRepresentation]);
     47 }
     48 
     49 }  // namespace
     50 
     51 void ResourceBundle::LoadCommonResources() {
     52   AddDataPackFromPath(GetResourcesPakFilePath(@"chrome_100_percent",
     53                         nil), SCALE_FACTOR_100P);
     54   AddDataPackFromPath(GetResourcesPakFilePath(@"webkit_resources_100_percent",
     55                         nil), SCALE_FACTOR_100P);
     56 
     57   // On Mac we load 1x and 2x resources and we let the UI framework decide
     58   // which one to use.
     59   if (IsScaleFactorSupported(SCALE_FACTOR_200P)) {
     60     AddDataPackFromPath(GetResourcesPakFilePath(@"chrome_200_percent",
     61                           nil), SCALE_FACTOR_200P);
     62     AddDataPackFromPath(GetResourcesPakFilePath(@"webkit_resources_200_percent",
     63                           nil), SCALE_FACTOR_200P);
     64   }
     65 }
     66 
     67 base::FilePath ResourceBundle::GetLocaleFilePath(const std::string& app_locale,
     68                                                  bool test_file_exists) {
     69   NSString* mac_locale = base::SysUTF8ToNSString(app_locale);
     70 
     71   // Mac OS X uses "_" instead of "-", so swap to get a Mac-style value.
     72   mac_locale = [mac_locale stringByReplacingOccurrencesOfString:@"-"
     73                                                      withString:@"_"];
     74 
     75   // On disk, the "en_US" resources are just "en" (http://crbug.com/25578).
     76   if ([mac_locale isEqual:@"en_US"])
     77     mac_locale = @"en";
     78 
     79   base::FilePath locale_file_path =
     80       GetResourcesPakFilePath(@"locale", mac_locale);
     81 
     82   if (delegate_) {
     83     locale_file_path =
     84         delegate_->GetPathForLocalePack(locale_file_path, app_locale);
     85   }
     86 
     87   // Don't try to load empty values or values that are not absolute paths.
     88   if (locale_file_path.empty() || !locale_file_path.IsAbsolute())
     89     return base::FilePath();
     90 
     91   if (test_file_exists && !base::PathExists(locale_file_path))
     92     return base::FilePath();
     93 
     94   return locale_file_path;
     95 }
     96 
     97 gfx::Image& ResourceBundle::GetNativeImageNamed(int resource_id, ImageRTL rtl) {
     98   // Flipped images are not used on Mac.
     99   DCHECK_EQ(rtl, RTL_DISABLED);
    100 
    101   // Check to see if the image is already in the cache.
    102   {
    103     base::AutoLock lock(*images_and_fonts_lock_);
    104     if (images_.count(resource_id)) {
    105       if (!images_[resource_id].HasRepresentation(gfx::Image::kImageRepCocoa)) {
    106         DLOG(WARNING) << "ResourceBundle::GetNativeImageNamed() is returning a"
    107           << " cached gfx::Image that isn't backed by an NSImage. The image"
    108           << " will be converted, rather than going through the NSImage loader."
    109           << " resource_id = " << resource_id;
    110       }
    111       return images_[resource_id];
    112     }
    113   }
    114 
    115   gfx::Image image;
    116   if (delegate_)
    117     image = delegate_->GetNativeImageNamed(resource_id, rtl);
    118 
    119   if (image.IsEmpty()) {
    120     base::scoped_nsobject<NSImage> ns_image;
    121     for (size_t i = 0; i < data_packs_.size(); ++i) {
    122       scoped_refptr<base::RefCountedStaticMemory> data(
    123           data_packs_[i]->GetStaticMemory(resource_id));
    124       if (!data.get())
    125         continue;
    126 
    127       base::scoped_nsobject<NSData> ns_data(
    128           [[NSData alloc] initWithBytes:data->front() length:data->size()]);
    129       if (!ns_image.get()) {
    130         ns_image.reset([[NSImage alloc] initWithData:ns_data]);
    131       } else {
    132         NSImageRep* image_rep = [NSBitmapImageRep imageRepWithData:ns_data];
    133         if (image_rep)
    134           [ns_image addRepresentation:image_rep];
    135       }
    136     }
    137 
    138     if (!ns_image.get()) {
    139       LOG(WARNING) << "Unable to load image with id " << resource_id;
    140       NOTREACHED();  // Want to assert in debug mode.
    141       return GetEmptyImage();
    142     }
    143 
    144     image = gfx::Image(ns_image.release());
    145   }
    146 
    147   base::AutoLock lock(*images_and_fonts_lock_);
    148 
    149   // Another thread raced the load and has already cached the image.
    150   if (images_.count(resource_id))
    151     return images_[resource_id];
    152 
    153   images_[resource_id] = image;
    154   return images_[resource_id];
    155 }
    156 
    157 }  // namespace ui
    158