Home | History | Annotate | Download | only in modules 
      1 # Copyright 2014 The Chromium Authors. All rights reserved.
      2 # Use of this source code is governed by a BSD-style license that can be
      3 # found in the LICENSE file.
      4 
      5 import("//third_party/WebKit/Source/bindings/bindings.gni")
      6 import("//third_party/WebKit/Source/bindings/modules/v8/generated.gni")
      7 import("//third_party/WebKit/Source/build/make_file_arrays.gni")
      8 import("//third_party/WebKit/Source/build/scripts/scripts.gni")
      9 import("//third_party/WebKit/Source/modules/modules.gni")
     10 
     11 visibility = "//third_party/WebKit/Source/*"
     12 
     13 # GYP version: WebKit/Source/modules/modules.gyp:modules
     14 source_set("modules") {
     15   visibility = "//third_party/WebKit/*"
     16 
     17   sources = rebase_path(modules_files, ".", "//")
     18   sources += rebase_path(bindings_modules_generated_aggregate_files, ".", "//")
     19 
     20   if (!is_win) {
     21     sources -= [
     22       "webdatabase/sqlite/SQLiteFileSystemWin.cpp",
     23     ]
     24   }
     25   if (!is_posix) {
     26     sources -= [
     27       "webdatabase/sqlite/SQLiteFileSystemPosix.cpp",
     28     ]
     29   }
     30 
     31   configs += [
     32     "//third_party/WebKit/Source:config",
     33     "//third_party/WebKit/Source:inside_blink",
     34   ]
     35 
     36   deps = [
     37     ":make_modules_generated",
     38     ":modules_fetch_polyfill",
     39     ":modules_cache_polyfill",
     40     ":modules_cache_storage_polyfill",
     41     "//third_party/WebKit/Source/core",
     42     "//third_party/sqlite",
     43     "//third_party/zlib",
     44   ]
     45 
     46   if (is_win) {
     47     cflags = [
     48       "/wd4267",  # Size to int truncations.
     49       "/wd4334",  # Result of 32-bit shift implicitly converted to 64 bits.
     50     ]
     51   }
     52 }
     53 
     54 # GYP version: WebKit/Source/modules/modules.gyp:modules (FetchPolyfill action)
     55 make_file_arrays("modules_fetch_polyfill") {
     56   filename = "FetchPolyfill"
     57   resources = [
     58     "serviceworkers/polyfills/fetchPolyfill.js",
     59   ]
     60   namespace = "WebCore"
     61 }
     62 
     63 # GYP version: WebKit/Source/modules/modules.gyp:modules (CachePolyfill action)
     64 make_file_arrays("modules_cache_polyfill") {
     65   filename = "CachePolyfill"
     66   resources = [
     67     "serviceworkers/polyfills/cachePolyfill.js",
     68   ]
     69   namespace = "WebCore"
     70 }
     71 
     72 # GYP version: WebKit/Source/modules/modules.gyp:modules (CacheStoragePolyfill action)
     73 make_file_arrays("modules_cache_storage_polyfill") {
     74   filename = "CacheStoragePolyfill"
     75   resources = [
     76     "serviceworkers/polyfills/cacheStoragePolyfill.js",
     77   ]
     78   namespace = "WebCore"
     79 }
     80 
     81 # GYP version: WebKit/Source/modules/modules.gyp:modules_testing
     82 source_set("modules_testing") {
     83   sources = modules_testing_files
     84 
     85   configs += [
     86     "//third_party/WebKit/Source:config",
     87     "//third_party/WebKit/Source:inside_blink",
     88   ]
     89 
     90   deps = [
     91     "//third_party/WebKit/Source/core",
     92   ]
     93 }
     94 
     95 # GYP version: WebKit/Source/modules/modules.gyp:make_modules_generated
     96 group("make_modules_generated") {
     97   deps = [
     98     "//third_party/WebKit/Source/core:core_event_interfaces",
     99     "//third_party/WebKit/Source/bindings/modules:bindings_modules_generated",
    100   ]
    101 }
    102