Home | History | Annotate | Download | only in objc 
      1 /*
      2  * libjingle
      3  * Copyright 2013, Google Inc.
      4  *
      5  * Redistribution and use in source and binary forms, with or without
      6  * modification, are permitted provided that the following conditions are met:
      7  *
      8  *  1. Redistributions of source code must retain the above copyright notice,
      9  *     this list of conditions and the following disclaimer.
     10  *  2. Redistributions in binary form must reproduce the above copyright notice,
     11  *     this list of conditions and the following disclaimer in the documentation
     12  *     and/or other materials provided with the distribution.
     13  *  3. The name of the author may not be used to endorse or promote products
     14  *     derived from this software without specific prior written permission.
     15  *
     16  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR IMPLIED
     17  * WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
     18  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO
     19  * EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
     20  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
     21  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
     22  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
     23  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
     24  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
     25  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
     26  */
     27 
     28 #if !defined(__has_feature) || !__has_feature(objc_arc)
     29 #error "This file requires ARC support."
     30 #endif
     31 
     32 #import "RTCMediaStreamTrack+Internal.h"
     33 #import "RTCEnumConverter.h"
     34 
     35 namespace webrtc {
     36 
     37 class RTCMediaStreamTrackObserver : public ObserverInterface {
     38  public:
     39   RTCMediaStreamTrackObserver(RTCMediaStreamTrack* track) { _track = track; }
     40 
     41   virtual void OnChanged() OVERRIDE {
     42     [_track.delegate mediaStreamTrackDidChange:_track];
     43   }
     44 
     45  private:
     46   __weak RTCMediaStreamTrack* _track;
     47 };
     48 }
     49 
     50 @implementation RTCMediaStreamTrack {
     51   talk_base::scoped_refptr<webrtc::MediaStreamTrackInterface> _mediaTrack;
     52   talk_base::scoped_ptr<webrtc::RTCMediaStreamTrackObserver> _observer;
     53 }
     54 
     55 @synthesize label;
     56 
     57 - (BOOL)isEqual:(id)other {
     58   // Equality is purely based on the label just like the C++ implementation.
     59   if (self == other)
     60     return YES;
     61   if (![other isKindOfClass:[self class]] ||
     62       ![self isKindOfClass:[other class]]) {
     63     return NO;
     64   }
     65   RTCMediaStreamTrack* otherMediaStream = (RTCMediaStreamTrack*)other;
     66   return [self.label isEqual:otherMediaStream.label];
     67 }
     68 
     69 - (NSUInteger)hash {
     70   return [self.label hash];
     71 }
     72 
     73 - (NSString*)kind {
     74   return @(self.mediaTrack->kind().c_str());
     75 }
     76 
     77 - (NSString*)label {
     78   return @(self.mediaTrack->id().c_str());
     79 }
     80 
     81 - (BOOL)isEnabled {
     82   return self.mediaTrack->enabled();
     83 }
     84 
     85 - (BOOL)setEnabled:(BOOL)enabled {
     86   return self.mediaTrack->set_enabled(enabled);
     87 }
     88 
     89 - (RTCTrackState)state {
     90   return [RTCEnumConverter convertTrackStateToObjC:self.mediaTrack->state()];
     91 }
     92 
     93 - (BOOL)setState:(RTCTrackState)state {
     94   return self.mediaTrack->set_state(
     95       [RTCEnumConverter convertTrackStateToNative:state]);
     96 }
     97 
     98 @end
     99 
    100 @implementation RTCMediaStreamTrack (Internal)
    101 
    102 - (id)initWithMediaTrack:
    103           (talk_base::scoped_refptr<webrtc::MediaStreamTrackInterface>)
    104       mediaTrack {
    105   if (!mediaTrack) {
    106     NSAssert(NO, @"nil arguments not allowed");
    107     self = nil;
    108     return nil;
    109   }
    110   if (self = [super init]) {
    111     _mediaTrack = mediaTrack;
    112     label = @(mediaTrack->id().c_str());
    113     _observer.reset(new webrtc::RTCMediaStreamTrackObserver(self));
    114     _mediaTrack->RegisterObserver(_observer.get());
    115   }
    116   return self;
    117 }
    118 
    119 - (void)dealloc {
    120   _mediaTrack->UnregisterObserver(_observer.get());
    121 }
    122 
    123 - (talk_base::scoped_refptr<webrtc::MediaStreamTrackInterface>)mediaTrack {
    124   return _mediaTrack;
    125 }
    126 
    127 @end
    128