Home | History | Annotate | Download | only in smali 
      1 /*
      2  * Copyright 2012, Google Inc.
      3  * All rights reserved.
      4  *
      5  * Redistribution and use in source and binary forms, with or without
      6  * modification, are permitted provided that the following conditions are
      7  * met:
      8  *
      9  *     * Redistributions of source code must retain the above copyright
     10  * notice, this list of conditions and the following disclaimer.
     11  *     * Redistributions in binary form must reproduce the above
     12  * copyright notice, this list of conditions and the following disclaimer
     13  * in the documentation and/or other materials provided with the
     14  * distribution.
     15  *     * Neither the name of Google Inc. nor the names of its
     16  * contributors may be used to endorse or promote products derived from
     17  * this software without specific prior written permission.
     18  *
     19  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
     20  * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
     21  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
     22  * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
     23  * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
     24  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
     25  * LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
     26  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
     27  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
     28  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
     29  * OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
     30  */
     31 
     32 apply plugin: 'idea'
     33 
     34 version = '2.0.5'
     35 
     36 def jarVersion = version
     37 
     38 if (!('release' in gradle.startParameter.taskNames)) {
     39     def versionSuffix
     40     try {
     41         def git = org.eclipse.jgit.api.Git.open(file('.'))
     42         def head = git.getRepository().getRef("HEAD")
     43         versionSuffix = head.getObjectId().abbreviate(8).name()
     44 
     45         if (!git.status().call().clean) {
     46             versionSuffix += '-dirty'
     47         }
     48     } catch (Exception) {
     49         // In case we can't get the commit for some reason,
     50         // just use -dev
     51         versionSuffix = 'dev'
     52     }
     53 
     54     def baseVersion = version
     55     version = baseVersion + '-' + versionSuffix
     56 
     57     // use something like module-1.2.3-dev.jar for the jar name, rather than the full
     58     // module-1.2.3-001afe02-dirty.jar
     59     jarVersion = baseVersion + '-dev'
     60 }
     61 
     62 // Note: please don't use this. This is strictly for the official releases
     63 // that are posted on, e.g. the bitbucket download page.
     64 task release() {
     65 }
     66 
     67 // The projects that get pushed to maven
     68 def maven_release_projects = ['smali', 'baksmali', 'dexlib2', 'util']
     69 
     70 subprojects {
     71     apply plugin: 'java'
     72     apply plugin: 'idea'
     73 
     74     if (JavaVersion.current().isJava8Compatible()) {
     75         allprojects {
     76             tasks.withType(Javadoc) {
     77                 options.addStringOption('Xdoclint:none', '-quiet')
     78             }
     79         }
     80     }
     81 
     82     version = parent.version
     83 
     84     ext {
     85         depends = [guava: 'com.google.guava:guava:18.0',
     86                    findbugs: 'com.google.code.findbugs:jsr305:1.3.9',
     87                    junit: 'junit:junit:4.6',
     88                    antlr_runtime: 'org.antlr:antlr-runtime:3.5.2',
     89                    antlr: 'org.antlr:antlr:3.5.2',
     90                    stringtemplate: 'org.antlr:stringtemplate:3.2.1',
     91                    commons_cli: 'commons-cli:commons-cli:1.2',
     92                    jflex: 'de.jflex:jflex:1.4.3',
     93                    proguard: 'net.sf.proguard:proguard-base:4.8'
     94          ]
     95     }
     96 
     97     jar {
     98         version = jarVersion
     99     }
    100 
    101     repositories {
    102         mavenCentral()
    103     }
    104 
    105     if (project.name in maven_release_projects) {
    106         apply plugin: 'maven'
    107         apply plugin: 'signing'
    108 
    109         group = 'org.smali'
    110 
    111         task javadocJar(type: Jar, dependsOn: javadoc) {
    112             classifier = 'javadoc'
    113             from 'build/docs/javadoc'
    114         }
    115 
    116         task sourcesJar(type: Jar) {
    117             classifier = 'sources'
    118             from sourceSets.main.allJava
    119         }
    120 
    121         artifacts {
    122             archives javadocJar
    123             archives sourcesJar
    124         }
    125 
    126         signing {
    127             required { gradle.taskGraph.hasTask("uploadArchives") }
    128             sign configurations.archives
    129         }
    130 
    131         uploadArchives {
    132             repositories.mavenDeployer {
    133                 configuration = configurations.archives
    134 
    135                 beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
    136 
    137                 if (rootProject.hasProperty('sonatypeUsername') && rootProject.hasProperty('sonatypePassword')) {
    138                     repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
    139                         authentication(userName: sonatypeUsername, password: sonatypePassword)
    140                     }
    141                 }
    142 
    143                 pom.artifactId = project.name
    144 
    145                 pom.project {
    146                     name project.name
    147                     url 'http://smali.org'
    148                     packaging 'jar'
    149                     licenses {
    150                         license {
    151                             name 'The BSD 3-Clause License'
    152                             url 'http://opensource.org/licenses/BSD-3-Clause'
    153                             distribution 'repo'
    154                         }
    155                     }
    156                     scm {
    157                         connection 'scm:git:git://github.com/JesusFreke/smali.git'
    158                         developerConnection 'scm:git:git (at) github.com:JesusFreke/smali.git'
    159                     }
    160                     developers {
    161                         developer {
    162                             id 'jesusfreke'
    163                             name 'Ben Gruver'
    164                             email 'jesusfreke (at) jesusfreke.com'
    165                         }
    166                     }
    167                 }
    168             }
    169         }
    170 
    171         tasks.getByPath(':release').dependsOn(uploadArchives)
    172     }
    173 }
    174 
    175 buildscript {
    176     repositories {
    177         mavenCentral()
    178     }
    179     dependencies {
    180         classpath 'org.eclipse.jgit:org.eclipse.jgit:2.0.0.201206130900-r'
    181     }
    182 }
    183 
    184 task wrapper(type: Wrapper) {
    185     gradleVersion = '1.10'
    186 }