Home | History | Annotate | Download | only in appcompat 
      1 apply plugin: 'com.android.library'
      2 
      3 archivesBaseName = 'appcompat-v7'
      4 
      5 dependencies {
      6     compile project(':support-v4')
      7     compile project(':support-vector-drawable')
      8     compile project(':support-animated-vector-drawable')
      9 
     10     androidTestCompile ('com.android.support.test:runner:0.4.1') {
     11         exclude module: 'support-annotations'
     12     }
     13     androidTestCompile ('com.android.support.test.espresso:espresso-core:2.2.1') {
     14         exclude module: 'support-annotations'
     15     }
     16     androidTestCompile 'org.mockito:mockito-core:1.9.5'
     17     androidTestCompile 'com.google.dexmaker:dexmaker:1.2'
     18     androidTestCompile 'com.google.dexmaker:dexmaker-mockito:1.2'
     19     testCompile 'junit:junit:4.12'
     20 }
     21 
     22 android {
     23     compileSdkVersion project.ext.currentSdk
     24 
     25     defaultConfig {
     26         minSdkVersion 7
     27         testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
     28         // This disables the builds tools automatic vector -> PNG generation
     29         generatedDensities = []
     30     }
     31 
     32     sourceSets {
     33         main.manifest.srcFile 'AndroidManifest.xml'
     34         main.java.srcDir 'src'
     35         main.res.srcDirs 'res', 'res-public'
     36         main.assets.srcDir 'assets'
     37         main.resources.srcDir 'src'
     38 
     39         androidTest.setRoot('tests')
     40         androidTest.java.srcDir 'tests/src'
     41         androidTest.res.srcDir 'tests/res'
     42         androidTest.manifest.srcFile 'tests/AndroidManifest.xml'
     43     }
     44 
     45     compileOptions {
     46         sourceCompatibility JavaVersion.VERSION_1_7
     47         targetCompatibility JavaVersion.VERSION_1_7
     48     }
     49 
     50     aaptOptions {
     51         additionalParameters "--no-version-vectors"
     52     }
     53 
     54     lintOptions {
     55         // TODO: fix errors and reenable.
     56         abortOnError false
     57     }
     58 }
     59 
     60 android.libraryVariants.all { variant ->
     61     def name = variant.buildType.name
     62 
     63     if (name.equals(com.android.builder.core.BuilderConstants.DEBUG)) {
     64         return; // Skip debug builds.
     65     }
     66     def suffix = name.capitalize()
     67 
     68     def jarTask = project.tasks.create(name: "jar${suffix}", type: Jar){
     69         dependsOn variant.javaCompile
     70         from variant.javaCompile.destinationDir
     71         from 'LICENSE.txt'
     72     }
     73     def javadocTask = project.tasks.create(name: "javadoc${suffix}", type: Javadoc) {
     74         source android.sourceSets.main.java
     75         classpath = files(variant.javaCompile.classpath.files) + files(
     76                 "${android.sdkDirectory}/platforms/${android.compileSdkVersion}/android.jar")
     77     }
     78 
     79     def javadocJarTask = project.tasks.create(name: "javadocJar${suffix}", type: Jar) {
     80         classifier = 'javadoc'
     81         from 'build/docs/javadoc'
     82     }
     83 
     84     def sourcesJarTask = project.tasks.create(name: "sourceJar${suffix}", type: Jar) {
     85         classifier = 'sources'
     86         from android.sourceSets.main.java.srcDirs
     87     }
     88 
     89     artifacts.add('archives', javadocJarTask);
     90     artifacts.add('archives', sourcesJarTask);
     91 }
     92 
     93 uploadArchives {
     94     repositories {
     95         mavenDeployer {
     96             repository(url: uri(rootProject.ext.supportRepoOut)) {
     97             }
     98 
     99             pom.project {
    100                 name 'Android AppCompat Library v7'
    101                 description "The Support Library is a static library that you can add to your Android application in order to use APIs that are either not available for older platform versions or utility APIs that aren't a part of the framework APIs. Compatible on devices running API 4 or later."
    102                 url 'http://developer.android.com/tools/extras/support-library.html'
    103                 inceptionYear '2011'
    104 
    105                 licenses {
    106                     license {
    107                         name 'The Apache Software License, Version 2.0'
    108                         url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
    109                         distribution 'repo'
    110                     }
    111                 }
    112 
    113                 scm {
    114                     url "http://source.android.com"
    115                     connection "scm:git:https://android.googlesource.com/platform/frameworks/support"
    116                 }
    117                 developers {
    118                     developer {
    119                         name 'The Android Open Source Project'
    120                     }
    121                 }
    122             }
    123         }
    124     }
    125 }