Home | History | Annotate | Download | only in driver 
      1 set( LLVM_LINK_COMPONENTS
      2   ${LLVM_TARGETS_TO_BUILD}
      3   Analysis
      4   CodeGen
      5   Core
      6   IPO
      7   InstCombine
      8   Instrumentation
      9   MC
     10   MCParser
     11   ObjCARCOpts
     12   Option
     13   ScalarOpts
     14   Support
     15   TransformUtils
     16   Vectorize
     17   )
     18 
     19 option(CLANG_PLUGIN_SUPPORT "Build clang with plugin support" ON)
     20 
     21 # Support plugins. This must be before add_clang_executable as it reads
     22 # LLVM_NO_DEAD_STRIP.
     23 if(CLANG_PLUGIN_SUPPORT)
     24   set(LLVM_NO_DEAD_STRIP 1)
     25 endif()
     26 
     27 add_clang_executable(clang
     28   driver.cpp
     29   cc1_main.cpp
     30   cc1as_main.cpp
     31   )
     32 
     33 target_link_libraries(clang
     34   clangBasic
     35   clangCodeGen
     36   clangDriver
     37   clangFrontend
     38   clangFrontendTool
     39   )
     40 
     41 if(WIN32 AND NOT CYGWIN)
     42   # Prevent versioning if the buildhost is targeting for Win32.
     43 else()
     44   set_target_properties(clang PROPERTIES VERSION ${CLANG_EXECUTABLE_VERSION})
     45 endif()
     46 
     47 # Support plugins.
     48 if(CLANG_PLUGIN_SUPPORT)
     49   export_executable_symbols(clang)
     50 endif()
     51 
     52 add_dependencies(clang clang-headers)
     53 
     54 install(TARGETS clang
     55   RUNTIME DESTINATION bin
     56   COMPONENT clang)
     57 
     58 if(NOT CMAKE_CONFIGURATION_TYPES)
     59   add_custom_target(install-clang
     60     DEPENDS clang
     61     COMMAND "${CMAKE_COMMAND}"
     62             -DCMAKE_INSTALL_COMPONENT=clang
     63             -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
     64 endif()
     65 
     66 if(NOT CLANG_LINKS_TO_CREATE)
     67   set(CLANG_LINKS_TO_CREATE clang++ clang-cl)
     68 
     69   if (WIN32)
     70     list(APPEND CLANG_LINKS_TO_CREATE ../msbuild-bin/cl)
     71   endif()
     72 endif()
     73 
     74 foreach(link ${CLANG_LINKS_TO_CREATE})
     75   add_clang_symlink(${link} clang)
     76 endforeach()
     77 
     78 # Configure plist creation for OS X.
     79 set (TOOL_INFO_PLIST "Info.plist" CACHE STRING "Plist name")
     80 if (APPLE)  
     81   if (CLANG_VENDOR)
     82     set(TOOL_INFO_NAME "${CLANG_VENDOR} clang")
     83   else()
     84     set(TOOL_INFO_NAME "clang")
     85   endif()
     86 
     87   set(TOOL_INFO_UTI "${CLANG_VENDOR_UTI}")
     88   set(TOOL_INFO_VERSION "${CLANG_VERSION}")
     89   set(TOOL_INFO_BUILD_VERSION "${LLVM_MAJOR_VERSION}.${LLVM_MINOR_VERSION}")
     90   
     91   set(TOOL_INFO_PLIST_OUT "${CMAKE_CURRENT_BINARY_DIR}/${TOOL_INFO_PLIST}")
     92   target_link_libraries(clang
     93     "-Wl,-sectcreate,__TEXT,__info_plist,${TOOL_INFO_PLIST_OUT}")
     94   configure_file("${TOOL_INFO_PLIST}.in" "${TOOL_INFO_PLIST_OUT}" @ONLY)
     95   
     96   set(TOOL_INFO_UTI)
     97   set(TOOL_INFO_NAME)
     98   set(TOOL_INFO_VERSION)
     99   set(TOOL_INFO_BUILD_VERSION)
    100 endif()
    101 
    102 if(CLANG_ORDER_FILE)
    103   target_link_libraries(clang "-Wl,-order_file,${CLANG_ORDER_FILE}")
    104 endif()
    105 
    106 if(WITH_POLLY AND LINK_POLLY_INTO_TOOLS)
    107   target_link_libraries(clang Polly)
    108   if(POLLY_LINK_LIBS)
    109     foreach(lib ${POLLY_LINK_LIBS})
    110       target_link_libraries(clang ${lib})
    111     endforeach(lib)
    112   endif(POLLY_LINK_LIBS)
    113 endif(WITH_POLLY AND LINK_POLLY_INTO_TOOLS)
    114