Home | History | Annotate | Download | only in cmake 
      1 include(CheckLibraryExists)
      2 include(CheckCCompilerFlag)
      3 include(CheckCXXCompilerFlag)
      4 
      5 check_library_exists(c fopen "" LIBCXXABI_HAS_C_LIB)
      6 if (NOT LIBCXXABI_USE_COMPILER_RT)
      7   check_library_exists(gcc_s __gcc_personality_v0 "" LIBCXXABI_HAS_GCC_S_LIB)
      8 endif ()
      9 
     10 # libc++abi is built with -nodefaultlibs, so we want all our checks to also
     11 # use this option, otherwise we may end up with an inconsistency between
     12 # the flags we think we require during configuration (if the checks are
     13 # performed without -nodefaultlibs) and the flags that are actually
     14 # required during compilation (which has the -nodefaultlibs). libc is
     15 # required for the link to go through. We remove sanitizers from the
     16 # configuration checks to avoid spurious link errors.
     17 check_c_compiler_flag(-nodefaultlibs LIBCXXABI_HAS_NODEFAULTLIBS_FLAG)
     18 if (LIBCXXABI_HAS_NODEFAULTLIBS_FLAG)
     19   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -nodefaultlibs")
     20   if (LIBCXXABI_HAS_C_LIB)
     21     list(APPEND CMAKE_REQUIRED_LIBRARIES c)
     22   endif ()
     23   if (LIBCXXABI_USE_COMPILER_RT)
     24     list(APPEND CMAKE_REQUIRED_FLAGS -rtlib=compiler-rt)
     25     find_compiler_rt_library(builtins LIBCXXABI_BUILTINS_LIBRARY)
     26     list(APPEND CMAKE_REQUIRED_LIBRARIES "${LIBCXXABI_BUILTINS_LIBRARY}")
     27   elseif (LIBCXXABI_HAS_GCC_S_LIB)
     28     list(APPEND CMAKE_REQUIRED_LIBRARIES gcc_s)
     29   endif ()
     30   if (MINGW)
     31     # Mingw64 requires quite a few "C" runtime libraries in order for basic
     32     # programs to link successfully with -nodefaultlibs.
     33     if (LIBCXXABI_USE_COMPILER_RT)
     34       set(MINGW_RUNTIME ${LIBCXXABI_BUILTINS_LIBRARY})
     35     else ()
     36       set(MINGW_RUNTIME gcc_s gcc)
     37     endif()
     38     set(MINGW_LIBRARIES mingw32 ${MINGW_RUNTIME} moldname mingwex msvcrt advapi32
     39                         shell32 user32 kernel32 mingw32 ${MINGW_RUNTIME}
     40                         moldname mingwex msvcrt)
     41     list(APPEND CMAKE_REQUIRED_LIBRARIES ${MINGW_LIBRARIES})
     42   endif()
     43   if (CMAKE_C_FLAGS MATCHES -fsanitize OR CMAKE_CXX_FLAGS MATCHES -fsanitize)
     44     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fno-sanitize=all")
     45   endif ()
     46   if (CMAKE_C_FLAGS MATCHES -fsanitize-coverage OR CMAKE_CXX_FLAGS MATCHES -fsanitize-coverage)
     47     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fno-sanitize-coverage=edge,trace-cmp,indirect-calls,8bit-counters")
     48   endif ()
     49 endif ()
     50 
     51 # Check compiler flags
     52 check_c_compiler_flag(-funwind-tables         LIBCXXABI_HAS_FUNWIND_TABLES)
     53 check_cxx_compiler_flag(-fno-exceptions       LIBCXXABI_HAS_NO_EXCEPTIONS_FLAG)
     54 check_cxx_compiler_flag(-fno-rtti             LIBCXXABI_HAS_NO_RTTI_FLAG)
     55 check_cxx_compiler_flag(-fstrict-aliasing     LIBCXXABI_HAS_FSTRICT_ALIASING_FLAG)
     56 check_cxx_compiler_flag(-nostdinc++           LIBCXXABI_HAS_NOSTDINCXX_FLAG)
     57 check_cxx_compiler_flag(-Wall                 LIBCXXABI_HAS_WALL_FLAG)
     58 check_cxx_compiler_flag(-W                    LIBCXXABI_HAS_W_FLAG)
     59 check_cxx_compiler_flag(-Wunused-function     LIBCXXABI_HAS_WUNUSED_FUNCTION_FLAG)
     60 check_cxx_compiler_flag(-Wunused-variable     LIBCXXABI_HAS_WUNUSED_VARIABLE_FLAG)
     61 check_cxx_compiler_flag(-Wunused-parameter    LIBCXXABI_HAS_WUNUSED_PARAMETER_FLAG)
     62 check_cxx_compiler_flag(-Wstrict-aliasing     LIBCXXABI_HAS_WSTRICT_ALIASING_FLAG)
     63 check_cxx_compiler_flag(-Wstrict-overflow     LIBCXXABI_HAS_WSTRICT_OVERFLOW_FLAG)
     64 check_cxx_compiler_flag(-Wwrite-strings       LIBCXXABI_HAS_WWRITE_STRINGS_FLAG)
     65 check_cxx_compiler_flag(-Wchar-subscripts     LIBCXXABI_HAS_WCHAR_SUBSCRIPTS_FLAG)
     66 check_cxx_compiler_flag(-Wmismatched-tags     LIBCXXABI_HAS_WMISMATCHED_TAGS_FLAG)
     67 check_cxx_compiler_flag(-Wmissing-braces      LIBCXXABI_HAS_WMISSING_BRACES_FLAG)
     68 check_cxx_compiler_flag(-Wshorten-64-to-32    LIBCXXABI_HAS_WSHORTEN_64_TO_32_FLAG)
     69 check_cxx_compiler_flag(-Wsign-conversion     LIBCXXABI_HAS_WSIGN_CONVERSION_FLAG)
     70 check_cxx_compiler_flag(-Wsign-compare        LIBCXXABI_HAS_WSIGN_COMPARE_FLAG)
     71 check_cxx_compiler_flag(-Wshadow              LIBCXXABI_HAS_WSHADOW_FLAG)
     72 check_cxx_compiler_flag(-Wconversion          LIBCXXABI_HAS_WCONVERSION_FLAG)
     73 check_cxx_compiler_flag(-Wnewline-eof         LIBCXXABI_HAS_WNEWLINE_EOF_FLAG)
     74 check_cxx_compiler_flag(-Wundef               LIBCXXABI_HAS_WUNDEF_FLAG)
     75 check_cxx_compiler_flag(-pedantic             LIBCXXABI_HAS_PEDANTIC_FLAG)
     76 check_cxx_compiler_flag(-Werror               LIBCXXABI_HAS_WERROR_FLAG)
     77 check_cxx_compiler_flag(-Wno-error            LIBCXXABI_HAS_WNO_ERROR_FLAG)
     78 check_cxx_compiler_flag(/WX                   LIBCXXABI_HAS_WX_FLAG)
     79 check_cxx_compiler_flag(/WX-                  LIBCXXABI_HAS_NO_WX_FLAG)
     80 check_cxx_compiler_flag(/EHsc                 LIBCXXABI_HAS_EHSC_FLAG)
     81 check_cxx_compiler_flag(/EHs-                 LIBCXXABI_HAS_NO_EHS_FLAG)
     82 check_cxx_compiler_flag(/EHa-                 LIBCXXABI_HAS_NO_EHA_FLAG)
     83 check_cxx_compiler_flag(/GR-                  LIBCXXABI_HAS_NO_GR_FLAG)
     84 
     85 # Check libraries
     86 check_library_exists(dl dladdr "" LIBCXXABI_HAS_DL_LIB)
     87 check_library_exists(pthread pthread_once "" LIBCXXABI_HAS_PTHREAD_LIB)
     88 check_library_exists(c __cxa_thread_atexit_impl ""
     89   LIBCXXABI_HAS_CXA_THREAD_ATEXIT_IMPL)
     90