Home | History | Annotate | Download | only in src 
      1 # Allow the source files to find headers in src/
      2 include_directories(${PROJECT_SOURCE_DIR}/src)
      3 
      4 if (DEFINED BENCHMARK_CXX_LINKER_FLAGS)
      5   list(APPEND CMAKE_SHARED_LINKER_FLAGS ${BENCHMARK_CXX_LINKER_FLAGS})
      6   list(APPEND CMAKE_MODULE_LINKER_FLAGS ${BENCHMARK_CXX_LINKER_FLAGS})
      7 endif()
      8 
      9 file(GLOB
     10   SOURCE_FILES
     11     *.cc
     12     ${PROJECT_SOURCE_DIR}/include/benchmark/*.h
     13     ${CMAKE_CURRENT_SOURCE_DIR}/*.h)
     14 
     15 add_library(benchmark ${SOURCE_FILES})
     16 set_target_properties(benchmark PROPERTIES
     17   OUTPUT_NAME "benchmark"
     18   VERSION ${GENERIC_LIB_VERSION}
     19   SOVERSION ${GENERIC_LIB_SOVERSION}
     20 )
     21 target_include_directories(benchmark PUBLIC
     22     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/../include>
     23     )
     24 
     25 # Link threads.
     26 target_link_libraries(benchmark  ${BENCHMARK_CXX_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
     27 find_library(LIBRT rt)
     28 if(LIBRT)
     29   target_link_libraries(benchmark ${LIBRT})
     30 endif()
     31 
     32 # We need extra libraries on Windows
     33 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
     34   target_link_libraries(benchmark Shlwapi)
     35 endif()
     36 
     37 set(include_install_dir "include")
     38 set(lib_install_dir "lib/")
     39 set(bin_install_dir "bin/")
     40 set(config_install_dir "lib/cmake/${PROJECT_NAME}")
     41 set(pkgconfig_install_dir "lib/pkgconfig")
     42 
     43 set(generated_dir "${CMAKE_CURRENT_BINARY_DIR}/generated")
     44 
     45 set(version_config "${generated_dir}/${PROJECT_NAME}ConfigVersion.cmake")
     46 set(project_config "${generated_dir}/${PROJECT_NAME}Config.cmake")
     47 set(pkg_config "${generated_dir}/${PROJECT_NAME}.pc")
     48 set(targets_export_name "${PROJECT_NAME}Targets")
     49 
     50 set(namespace "${PROJECT_NAME}::")
     51 
     52 include(CMakePackageConfigHelpers)
     53 write_basic_package_version_file(
     54     "${version_config}" VERSION ${GIT_VERSION} COMPATIBILITY SameMajorVersion
     55 )
     56 
     57 configure_file("${PROJECT_SOURCE_DIR}/cmake/Config.cmake.in" "${project_config}" @ONLY)
     58 configure_file("${PROJECT_SOURCE_DIR}/cmake/benchmark.pc.in" "${pkg_config}" @ONLY)
     59 
     60 if (BENCHMARK_ENABLE_INSTALL)
     61   # Install target (will install the library to specified CMAKE_INSTALL_PREFIX variable)
     62   install(
     63     TARGETS benchmark
     64     EXPORT ${targets_export_name}
     65     ARCHIVE DESTINATION ${lib_install_dir}
     66     LIBRARY DESTINATION ${lib_install_dir}
     67     RUNTIME DESTINATION ${bin_install_dir}
     68     INCLUDES DESTINATION ${include_install_dir})
     69 
     70   install(
     71     DIRECTORY "${PROJECT_SOURCE_DIR}/include/benchmark"
     72     DESTINATION ${include_install_dir}
     73     FILES_MATCHING PATTERN "*.*h")
     74 
     75   install(
     76       FILES "${project_config}" "${version_config}"
     77       DESTINATION "${config_install_dir}")
     78 
     79   install(
     80       FILES "${pkg_config}"
     81       DESTINATION "${pkgconfig_install_dir}")
     82 
     83   install(
     84       EXPORT "${targets_export_name}"
     85       NAMESPACE "${namespace}"
     86       DESTINATION "${config_install_dir}")
     87 endif()
     88